Correlations matrix

Correlations matrix | BigML.com

FREE

Correlations matrix

Details:

Created	Thu, 8 Oct 2026 15:03:06 +0000
Published	Thu, 8 Oct 2026 17:25:48 +0000

Description:

Creates a matrix of correlations between the numeric and categorical fields in a dataset. The index used by default to measure correlation is eta squared (one-way ANOVA)

Tags:

BigMLer BigMLer_ThuOct0826_170305

URL:

https://bigml.com/user/whizzml/gallery/script/6ac7b0aa6a59afed275e482a

Script FREE

Source code

;; correlations-cross-tabs
;; creates the matrix of correlation values for the fields in a dataset
;;
;; Inputs:
;;   dataset-id: (string) Dataset ID
;;   s-fields: (list) List of fields to be analyzed
;;   options: (map) Arguments for the correlations creation
;;   c-index: (string) Index to be used to analyze correlation

(define (correlations-cross-tabs dataset-id s-fields options c-index)
  (let (ds (fetch dataset-id)
        fields (resource-fields ds)
        find-field-l (lambda (f) (find-field fields f))
        fields-list (if (empty? s-fields)
                        (iterate (acc [] field-id (keys fields))
                          (append acc (assoc (fields field-id) "id" field-id)))
                        (map find-field-l s-fields))
        of-fields-fn (lambda (x) (member? (x "optype")
                                          ["numeric" "categorical"]))
        f-name (lambda (x) (x "name" ""))
        of-fields (filter of-fields-fn fields-list)
        of-fields (sort-by-key "column" of-fields)
        headers (map f-name of-fields)
        c-ids (for (field of-fields)
                (create-and-wait-correlation (assoc options
                                                    "dataset"
                                                    dataset-id
                                                    "objective_field"
                                                    (field "id")))))
    (reduce (lambda (acc x) (if (member? c-index x)
                            (append acc (x 2))
                            acc))
            [headers]
            (correlation-metrics c-ids
                                 (map (lambda (x) (x "id"))  of-fields)))))

;; Transforms a 2D-matrix to a CSV string

(define (matrix-to-csv matrix)
  (join "\n" (for (row matrix)
                  (join "," row))))

;; Analyzes the contents of the list of correlations (one per field as
;; objective field)
;; The result is a list of lists that contain the name, and attributes for a
;; type of correlation measure. E.g.:
;;
;; ["one_way_anova", "eta_square", [[1, 0.1, 0.2]]]
;;
(define (correlation-metrics correlation-ids field-ids)
  (log-info correlation-ids field-ids)
  (iterate (acc [] corr-id correlation-ids)
    (log-info corr-id field-ids)
    (let (corrs ((fetch corr-id) ["correlations" "correlations"])
          blocks (iterate (acc [] c corrs)
                   (concat acc (id-to-col c field-ids))))
    (concat acc blocks))))


(define (id-to-col c field-ids)
  (let (name (c "name")
        results (c "result"))
    (for (k (keys (head (values results))))
      [name k (for (f-id field-ids)
                (results [f-id k] 1))])))

(define correlations-tab (matrix-to-csv
                           (correlations-cross-tabs dataset-id
                                                    fields
                                                    options
                                                    correlation-index)))

Description

Inputs

Outputs

License: Creative Commons Zero V1.0
Script FREE

Correlations matrix | BigML.com

Sending Request...

COMPANY

PRODUCT

BUSINESS

TRAINING

GALLERY

License

Embed this Script in your web site

COMPANY

PRODUCT

BUSINESS

TRAINING

GALLERY