Stacked prediction

Stacked prediction | BigML.com

FREE

Stacked prediction

Details:

Created	Thu, 8 Oct 2026 15:02:03 +0000
Published	Thu, 8 Oct 2026 17:25:59 +0000

Description:

Creates several kinds of predictors, runs them all on the same dataset, and appends the dataset with the most popular prediction

Tags:

BigMLer BigMLer_ThuOct0826_170202

URL:

https://bigml.com/user/whizzml/gallery/script/6ac7b06b9639eabb37d7527a

Script FREE

Source code

;; Extract for a batchpredction its associated dataset of results
(define (batch-dataset id)
  ((fetch (wait id)) "output_dataset_resource"))

;; Create a batchprediction for the given model and datasets,
;; with a map of additional options and using defaults appropriate
;; for model stacking
(define (make-batch ds-id mod-id)
  (let (mod (fetch mod-id) 
        name (if (= (resource-type mod-id) "ensemble")
               (if (contains? mod "boosting")
                 "ensemble-boosted"
                 (if (mod "randomize")
                   "ensemble-rdf"
                   "ensemble-bagging"))
               (resource-type mod-id)))
    (create-batchprediction ds-id mod-id {"all_fields" true
                                          "output_dataset" true
                                          "prediction_name" name})))

;; Auxiliary function to create the set of stack models
(define (create-stack-models train-id model-name param)
  (cond (= model-name "model") (create-model train-id param)
        (= model-name "ensemble") (create-ensemble train-id param)
        (= model-name "logisticregression") (create-logisticregression train-id param)
        (= model-name "lr") (create-logisticregression train-id param)
        (raise (str "Predictor name not recognized: " model-name))))

;; Auxiliary funtion to successively create batchpredictions using the
;; given models over the initial dataset ds-id.  Returns the final
;; dataset id.
(define (create-stack-predictions models ds-id)
  (reduce (lambda (did mid) (batch-dataset (make-batch did mid)))
          ds-id
          models))

;; Auxiliary function extracting the model_inputs of a model
(define (model-inputs mod-id)
  ((fetch mod-id) "input_fields"))

;; Lisp filter to find the most popular/average

(define (popular-filter id obj-id new-fields)
  (let (obj-optype ((fetch id) ["fields" obj-id "optype"])
        n (count new-fields)
        partial (map (lambda (x) (flatline "(f {{x}})")) new-fields))
    (if (= obj-optype "numeric")
        (flatline "(/ (+ @{partial}) {n})")
        (flatline "(let (combined (list @{partial}))"
                  "  (mode combined))"))))

;; Splits the given dataset, using half of it to create
;; an heterogeneous collection of models and the other
;; half to train a tree that predicts based on those other
;; models predictions.  Returns a map with the collection
;; of models (under the key "models") and the meta-prediction
;; as the value of the key "metamodel".  The key "result"
;; has as value a boolean flag indicating whether the
;; process was successful.
(define (make-stack train-id hold-id model-list params)
  (let (obj-id (dataset-get-objective-id train-id)
        models (map (lambda (x) 
                      (create-stack-models train-id (nth model-list x) 
                                                    (nth params x)))
                    (range (count model-list)))
        id (create-stack-predictions models hold-id)
        orig-fields (model-inputs (head models))
        new-fields (filter (lambda (n) 
                             (not (member? n (keys (resource-fields train-id))))) 
                           (keys (resource-fields id)))
        popular-id (create-dataset {"origin_dataset" id 
                                 "new_fields" [{"field" (popular-filter id obj-id new-fields)
                                                "name" "popular"}]})
        success? (resource-done? (fetch (wait popular-id))))
    {"models" models "dataset" popular-id "result" success?}))

(define popular-dataset ((make-stack training holdout model-list parameters) "dataset"))

Description

Inputs

Outputs

License: Creative Commons Zero V1.0
Script FREE

Stacked prediction | BigML.com

Sending Request...

COMPANY

PRODUCT

BUSINESS

TRAINING

GALLERY

License

Embed this Script in your web site

COMPANY

PRODUCT

BUSINESS

TRAINING

GALLERY